plugins {
    id 'java'
    id 'com.github.johnrengelman.shadow'
    id 'maven-publish'
    id 'signing'
}

group 'org.codemc.worldguardwrapper'
version parent.version

assemble.dependsOn shadowJar


repositories {
    mavenCentral()
    maven { url "https://maven.enginehub.org/repo/" }
    maven { url = 'https://hub.spigotmc.org/nexus/content/repositories/snapshots/' }
}

dependencies {
    api project(':api')
    api project(':implementation')
    compileOnly 'org.spigotmc:spigot-api:1.8.8-R0.1-SNAPSHOT'
    implementation 'org.javassist:javassist:3.29.2-GA'
    compileOnly 'org.projectlombok:lombok:1.18.26'
    annotationProcessor 'org.projectlombok:lombok:1.18.26'
}

shadowJar {
    dependencies {
        exclude(dependency('org.projectlombok:lombok'))
        exclude(dependency('org.jetbrains:annotations'))
    }
    relocate 'javassist', 'org.codemc.worldguardwrapper.libs.javassist'

    archiveFileName = "WorldGuardWrapper-${project.version}.jar"
}

compileJava.options.encoding = 'UTF-8'

tasks.withType(JavaCompile) {
    options.encoding = 'UTF-8'
}



publishing {
    publications {
        maven(MavenPublication) {
            groupId = 'org.codemc.worldguardwrapper'
            artifactId = 'worldguardwrapper'
            artifact("build/libs/WorldGuardWrapper-${project.version}.jar") {
                extension 'jar'
            }
        }
    }
    repositories {
        maven {
            name 'secure'
            url =  "https://repo.recorehosting.com/repository/maven-snapshots"
            credentials(org.gradle.api.credentials.PasswordCredentials)
        }
    }
}